通常，我們在數據庫中存儲數據。不過，如果希望數據的可移植性更強，我們可以把數據存儲XML文件中。
如果數據要被傳送到非Windows平台上的應用程序，那麼把數據保存在XML文件中是有好處的。請記住，XML有很強的跨平台可移植性，並且數據無需轉換！
首先，我們將學習如何創建並保存一個XML文件。下面的這個XML文件將被命名為"test.XML"，並被保存在服務器上的c目錄中。我們將使用ASP和微軟的XMLDOM對象來創建並保存這個XML文件：
<%
Dim xmlDoc, rootEl, child1, child2, p
'創建XML文檔
Set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")
'創建根元素並將之加入文檔
Set rootEl = xmlDoc.createElement("root")
xmlDoc.appendChild rootEl
'創建並加入子元素
Set child1 = xmlDoc.createElement("child1")
Set child2 = xmlDoc.createElement("child2")
rootEl.appendChild child1
rootEl.appendChild child2
'創建 XML processing instrUCtion
'並把它加到根元素之前
Set p=xmlDoc.createProcessingInstruction("xml","version='1.0'")
xmlDoc.insertBefore p,xmlDoc.childNodes(0)
'把文件保存到c目錄
xmlDoc.Save "c:\test.XML"
%>
如果您打開這個被保存的文件，它會使這個樣子("test.XML")：
<?XML version="1.0"?> <root> <child1 /> <child2 /> </root>
現在，我們看一個真實的表單例子。
我們首先看一下這個被用在例子中的Html表單：下面的Html表單要求用戶輸入他們的名字、國籍以及電子郵件地址。隨後這些信息會被寫到一個XML文件，以便存儲。
<html> <body> <form action="saveForm.ASP" method="post"> <h1>請輸入您的聯系信息：</h1> <label>名字: </label> <p><input type="text" id="fname" name="fname"></p> <label>姓氏: </label> <p><input type="text" id="lname" name="lname"></p> <label>國家: </label> <p><input type="text" id="country" name="country"></p> <label>郵件: </label> <p><input type="text" id="email" name="email"></p> <p> <input type="submit" id="BTn_sub" name="btn_sub" value="Submit"> <input type="reset" id="btn_res" name="btn_res" value="Reset"> </p> </form> </body> </Html>
用於以上Html表單的action被設置為"saveForm.asp"。"saveForm.asp"文件是一個ASP頁面，可循環遍表單域，並把它們的值存儲在一個XML文件之中：
<%
dim xmlDoc
dim rootEl,fieldName,fieldValue,attID
dim p,i
'如果有錯誤發生，不允許程序終止
On Error Resume Next
Set xmlDoc = server.CreateObject("Microsoft.XMLDOM")
xmlDoc.preserveWhiteSpace=true
'創建並向文檔添加根元素
Set rootEl = xmlDoc.createElement("customer")
xmlDoc.appendChild rootEl
'循環遍歷Form集
for i = 1 To Request.Form.Count
'除去表單中的button元素
if instr(1,Request.Form.Key(i),"btn_")=0 then
'創建field 和 value 元素，以及 id 屬性
Set fieldName = xmlDoc.createElement("field")
Set fieldValue = xmlDoc.createElement("value")
Set attID = xmlDoc.createAttribute("id")
'把當前表單域的名稱設置為id屬性的值
attID.Text = Request.Form.Key(i)
'把id屬性添加到field元素
fieldName.setAttributeNode attID
'把當前表單域的值設置為value元素的值
fieldValue.Text = Request.Form(i)
'將field元素作為根元素的子元素進行添加
rootEl.appendChild fieldName
'將value元素作為field元素的子元素進行添加
fieldName.appendChild fIEldValue
end if
next
'添加XML processing instruction
'並把它加到根元素之前
Set p = xmlDoc.createProcessingInstruction("xml","version='1.0'")
xmlDoc.insertBefore p,xmlDoc.childNodes(0)
'保存XML文件
xmlDoc.save "c:\Customer.xml"
'釋放所有的對象引用
set XMLDoc=nothing
set rootEl=nothing
set fieldName=nothing
set fIEldValue=nothing
set attID=nothing
set p=nothing
'測試是否有錯誤發生
if err.number<>0 then
response.write("Error: No information saved.")
else
response.write("Your information has been saved.")
end if
%>
注釋：如果被指定的XML文件名已經存在，那個文件會被覆蓋！
XML文件會由上面的代碼生成，大致的樣子是這樣的：("Customer.XML"):
<?XML version="1.0" ?>
<customer>
<field id="firstName">
<value>Hege</value>
</field>
<field id="lastName">
<value>Refsnes</value>
</field>
<field id="country">
<value>Norway</value>
</field>
<field id="email">
<value>mymail@myaddress.com</value>
</fIEld>
</customer>