DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
Delphi 實作:把資料集轉存為 XML 檔案
編輯:XML詳解     

把 TDataset 的內容輸出成 XML,在 Delphi 裡有兩條路可走:一條是純手寫字串,把資料集逐列寫進檔案;另一條是藉助 Microsoft XML DOM(MSXML)建立節點樹再存檔。本文兩種都示範。

轉換約定

先定義 XML 的結構規則,後續實作才有依據:

  • XML 的根節點名稱與資料表名稱相同(本例為 country)。
  • 每一筆記錄用一組標籤包起來,方便區隔。
  • 每個欄位則以其欄位名稱作為標籤名稱。
<country>
  <Records>
    <Name>Argentina</Name>
    <Capital>Buenos Aires</Capital>
    <Continent>South America</Continent>
    <Area>2777815</Area>
    <Population>32300003</Population>
  </Records>
  ...
</country>

做法一:直接寫檔(單元 DS2XML)

這個版本不依賴任何外部元件,只用 TFileStream 逐段寫出 XML 文字,並針對欄位型別做對應的格式化。

unit DS2XML;

interface

uses
  Classes, DB;

procedure DatasetToXML(Dataset: TDataset; FileName: string);

implementation

uses SysUtils;

var
  SourceBuffer: PChar;

procedure WriteString(Stream: TFileStream; s: string);
begin
  StrPCopy(SourceBuffer, s);
  Stream.Write(SourceBuffer[0], StrLen(SourceBuffer));
end;

function XMLFieldType(fld: TField): string;
begin
  case fld.DataType of
    ftString:   Result := '"string" WIDTH="' + IntToStr(fld.Size) + '"';
    ftSmallint: Result := '"i4"';
    ftInteger:  Result := '"i4"';
    ftWord:     Result := '"i4"';
    ftBoolean:  Result := '"boolean"';
    ftAutoInc:  Result := '"i4" SUBTYPE="Autoinc"';
    ftFloat:    Result := '"r8"';
    ftCurrency: Result := '"r8" SUBTYPE="Money"';
    ftBCD:      Result := '"r8"';
    ftDate:     Result := '"date"';
    ftTime:     Result := '"time"';
    ftDateTime: Result := '"datetime"';
  end;
  if fld.Required then Result := Result + ' required="true"';
  if fld.ReadOnly then Result := Result + ' readonly="true"';
end;

function GetDig(i, j: Word): string;
begin
  Result := IntToStr(i);
  while Length(Result) < j do
    Result := '0' + Result;
end;

function GetFieldStr(Field: TField): string;
var
  Hour, Min, Sec, MSec: Word;
begin
  case Field.DataType of
    ftBoolean: Result := UpperCase(Field.AsString);
    ftDate:    Result := FormatDateTime('yyyymmdd', Field.AsDateTime);
    ftTime:    Result := FormatDateTime('hhnnss', Field.AsDateTime);
    ftDateTime:
      begin
        Result := FormatDateTime('yyyymmdd', Field.AsDateTime);
        DecodeTime(Field.AsDateTime, Hour, Min, Sec, MSec);
        if (Hour <> 0) or (Min <> 0) or (Sec <> 0) or (MSec <> 0) then
          Result := Result + 'T' + GetDig(Hour, 2) + ':' + GetDig(Min, 2) +
                    ':' + GetDig(Sec, 2) + GetDig(MSec, 3);
      end;
  else
    Result := Field.AsString;
  end;
end;

procedure DatasetToXML(Dataset: TDataset; FileName: string);
var
  Stream: TFileStream;
  bkmark: TBookmark;
  i: Integer;
begin
  Stream := TFileStream.Create(FileName, fmCreate);
  SourceBuffer := StrAlloc(1024);
  try
    with Dataset do
    begin
      DisableControls;
      bkmark := GetBookmark;
      First;
      // 逐列輸出,最後回到原定位並恢復控制項
      while not EOF do
      begin
        for i := 0 to FieldCount - 1 do
          WriteString(Stream, ' ' + Fields[i].FieldName + '="' +
                             GetFieldStr(Fields[i]) + '"');
        WriteString(Stream, ' />'#13#10);
        Next;
      end;
      GotoBookmark(bkmark);
      EnableControls;
    end;
  finally
    Stream.Free;
    StrDispose(SourceBuffer);
  end;
end;

end.

做法二:使用 MSXML DOM

先在主視窗放一個 Button 與 Table 元件,並設定資料表屬性:

DatabaseName : DBDEMOS
Name         : Table1
TableName    : country   { 不要帶 .db 副檔名 }
Active       : True

接著選擇「Project / Import Type Library」,在清單中挑選「Microsoft XML, Version 2.0」,按下「Create Unit」。此舉會把 MSXML_TLB 單元加入專案,記得在要引用的單元 interface 區段裡 uses 它。然後宣告需要的變數:

DataList  : TStringList;
doc       : IXMLDOMDocument;
root, child, child1 : IXMLDOMElement;
nlist     : IXMLDOMNodeList;
dataRecord: string;

核心的 makeXML 函式如下,它會讀取 DBDEMOS 中 country 表的資料並產生 XML 檔案:

function TForm1.makeXML(table: TTable): Integer;
var
  i: Integer;
  XML, temp: String;
begin
  try
    table.Close;
    table.Open;
    XML := table.TableName;
    doc := CreateOleObject('Microsoft.XMLDOM') as IXMLDomDocument;

    // 根節點名稱 = 資料表名稱
    root := doc.createElement(XML);
    doc.appendChild(root);

    while not table.EOF do
    begin
      child := doc.createElement('Records');
      root.appendChild(child);
      for i := 0 to table.FieldCount - 1 do
      begin
        child1 := doc.createElement(table.Fields[i].FieldName);
        child.appendChild(child1);

        case TFieldType(Ord(table.Fields[i].DataType)) of
          ftString:
            if table.Fields[i].AsString = '' then temp := 'null'
            else temp := table.Fields[i].AsString;
          ftInteger, ftWord, ftSmallint:
            if table.Fields[i].AsInteger > 0
              then temp := IntToStr(table.Fields[i].AsInteger) else temp := '0';
          ftFloat, ftCurrency, ftBCD:
            if table.Fields[i].AsFloat > 0
              then temp := FloatToStr(table.Fields[i].AsFloat) else temp := '0';
          ftBoolean:
            if table.Fields[i].Value then temp := 'True' else temp := 'False';
          ftDate:
            if (not table.Fields[i].IsNull) or
               (Length(Trim(table.Fields[i].AsString)) > 0)
              then temp := FormatDateTime('MM/DD/YYYY', table.Fields[i].AsDateTime)
              else temp := '01/01/2000';
          ftDateTime:
            if (not table.Fields[i].IsNull) or
               (Length(Trim(table.Fields[i].AsString)) > 0)
              then temp := FormatDateTime('MM/DD/YYYY hh:nn:ss', table.Fields[i].AsDateTime)
              else temp := '01/01/2000 00:00:00';
          ftTime:
            if (not table.Fields[i].IsNull) or
               (Length(Trim(table.Fields[i].AsString)) > 0)
              then temp := FormatDateTime('hh:nn:ss', table.Fields[i].AsDateTime)
              else temp := '00:00:00';
        end;

        child1.appendChild(doc.createTextNode(temp));
      end;
      table.Next;
    end;

    doc.save(xml + '.xml');
    Result := 1;
  except
    on e: Exception do Result := -1;
  end;
end;

在按鈕的 OnClick 事件中呼叫即可:

procedure TForm1.Button1Click(Sender: TObject);
begin
  if makeXML(Table1) = 1 then
    ShowMessage('XML 已產生')
  else
    ShowMessage('產生 XML 檔案時發生錯誤');
end;

用 IE 5.0 以上版本打開 country.xml,就會看到前述結構的內容,包含 Argentina、Bolivia、Venezuela 等各筆 Records。

反向操作:把 XML 資料寫回資料表

由於 XML 裡的資料與 country 表內容一致,若要重新匯入而不先清空原資料,就會碰到主鍵衝突。因此匯入前必須先刪除既有記錄。

在主視窗再放一個 Button 與 Memo(用來顯示匯入狀態),Button2 的 OnClick 事件如下:

procedure TForm1.Button2Click(Sender: TObject);
var
  i, ret_val, count: Integer;
  strData: String;
begin
  try
    count := 1;
    DataList := TStringList.Create;
    Memo1.Clear;
    doc := CreateOleObject('Microsoft.XMLDOM') as IXMLDomDocument;
    doc.load('country.xml');
    nlist := doc.getElementsByTagName('Records');
    Memo1.Lines.Append('Table Name : country');
    Memo1.Lines.Append('---------------------');
    for i := 0 to nlist.Get_length - 1 do
    begin
      travelChildren(nlist.Get_item(i).Get_childNodes);
      strData := Copy(dataRecord, 2, Length(dataRecord));  // 去掉最前面的逗號
      Memo1.Lines.Append(strData);
      dataRecord := '';
      ret_val := insertintotable(DataList);
      if ret_val = 1 then
        Memo1.Lines.Append('資料寫入成功!')
      else if ret_val = -1 then
        Memo1.Lines.Append('更新失敗,請再試一次!');
      Memo1.Lines.Append('=================================' +
                         '==(Record no.: ' + IntToStr(count) + ')');
      DataList.Clear;
      Inc(count);
    end;
  except
    on e: Exception do ShowMessage(e.Message);
  end;
end;

nlist 裡存的是節點清單,第一個節點清單看起來就像前面那段 <Records> 結構。我們把它交給遞迴函式 travelChildren,由它沿著節點往下找出文字資料並放進 TStringList。跑完一輪之後,DataList 裡就會依序裝著 Argentina、Buenos Aires、South America、2777815、32300003,接著交給 insertintotable 完成一筆記錄的寫入。重複這個流程,就能把整份 XML 的資料匯回去。

procedure TForm1.travelChildren(nlist1: IXMLDOMNodeList);
var
  j: Integer;
  temp: String;
begin
  for j := 0 to nlist1.Get_length - 1 do
  begin
    // 節點類型 1 為 Element,5 為 EntityRef,都還有子節點
    if (nlist1.Get_item(j).Get_nodeType = 1) or
       (nlist1.Get_item(j).Get_nodeType = 5) then
      travelChildren(nlist1.Get_item(j).Get_childNodes)
    // 節點類型 3 是文字節點,也就是我們要的值
    else if nlist1.Get_item(j).Get_nodeType = 3 then
    begin
      temp := Trim(nlist1.Get_item(j).Get_nodeValue);
      dataRecord := dataRecord + ',' + temp;
      DataList.Add(temp);
    end;
  end;
end;

function TForm1.insertintotable(stpt: TStringList): Integer;
var
  i: Integer;
begin
  Table1.Close;
  Table1.Open;
  Table1.Insert;
  for i := 0 to stpt.Count - 1 do
    Table1.Fields[i].AsVariant := stpt[i];
  try
    Table1.Post;
    Result := 1;
  except
    on E: Exception do Result := -1;
  end;
end;

結語

把這個範例稍加推廣,就能套用到任何資料庫:資料先轉成 XML,透過網路(即使是網際網路)傳輸,再在終端節點更新資料庫。值得一提的是,本例尚未處理 &、<、>、單引號、雙引號等特殊字元;若你的資料含有這些字元,記得在產生 XML 時補上跳脫處理,或使用 MSXML DOM 建立節點的方式讓它自動處理。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved