DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
XMLHTTP 傳送中文亂碼的完整解法:URL 編碼與位元組轉碼
編輯:XML詳解     

用 XMLHTTP 送出純英文欄位一向沒問題,但只要表單裡出現中文,伺服器端收到的就是一堆問號或亂碼。這其實牽涉兩個各自獨立的環節:一是送出的中文沒有先做 URL 編碼,二是取回的中文內容被 XMLHTTP 用錯的編碼方式解讀。把這兩件事分別處理好,亂碼就會徹底消失。

Part I 正確送出中文內容

先看純英文表單是怎麼提交的:

<SCRIPT language="Javascript">
strA = "submit1=Submit&text1=scsdfsd";
var oReq = new ActiveXObject("MSXML2.XMLHTTP");
oReq.open("POST", "https://ServerName/VDir/TstResult.ASP", false);
oReq.setRequestHeader("Content-Length", strA.length);
oReq.setRequestHeader("CONTENT-TYPE", "application/x-www-form-urlencoded");
oReq.send(strA);
</SCRIPT>

把值換成中文之後,例如 strA = "submit1=Submit&text1=中文";,伺服器的 Request.Form("text1") 就會取不到值。用 Request.BinaryRead 把瀏覽器實際送出的內容印出來看,才會發現問題所在:表單送出前必須先做 URL 編碼,中文會變成 %D6%D0%CE%C4 這類形式的百分比轉義字元。其實 CONTENT-TYPE 寫的 application/x-www-form-urlencoded 已經把答案說清楚了——既然是 urlencoded,就得照這個格式編。於是只要自己動手轉換即可:

<SCRIPT language="VBScript">
Function URLEncoding(vstrIn)
    strReturn = ""
    For i = 1 To Len(vstrIn)
        ThisChr = Mid(vstrIn, i, 1)
        If Abs(Asc(ThisChr)) < &HFF Then
            strReturn = strReturn & ThisChr
        Else
            innerCode = Asc(ThisChr)
            If innerCode < 0 Then
                innerCode = innerCode + &H10000
            End If
            Hight8 = (innerCode And &HFF00) \ &HFF
            Low8 = innerCode And &HFF
            strReturn = strReturn & "%" & Hex(Hight8) & "%" & Hex(Low8)
        End If
    Next
    URLEncoding = strReturn
End Function

strA = URLEncoding("submit1=Submit&text1=中文")
oReq = CreateObject("MSXML2.XMLHTTP")
oReq.open "POST", "https://ServerName/VDir/TstResult.ASP", false
oReq.setRequestHeader "Content-Length", Len(strA)
oReq.setRequestHeader "CONTENT-TYPE", "application/x-www-form-urlencoded"
oReq.send strA
</SCRIPT>

這裡把前面的 JavaScript 改寫成 VBScript,並非無聊,原因請見下一節。

Part II 正確顯示取回的中文

若伺服器把表單內容寫進資料庫或檔案,中文一切正常。但如果你想直接看伺服器的 Response,問題就来了:回應內容不是 XML 時,responseXML 裡空空如也,於是改用 responseText,例如在最後加上 alert(oReq.responseText)——結果所有中文全變成方塊。

原因很單純:XMLHTTP 取得回應時預設它是 UTF-8。若回應是 XML,還能靠 encoding 宣告指定編碼;但 HTML 沒有這個機會,於是一段 GB2312 編碼的頁面就被硬當成 UTF-8 來解,不亂碼才是怪事。

好在仍有補救餘地:responseBody 屬性保留的是未經解碼的原始位元組,也就是伺服器實際送出的內容。剩下的難題是,它回傳的是一個 unsigned byte 陣列,要如何取值、又如何轉成 BSTR?這正是前述範例改用 VBScript 的理由——VBScript 辦得到,JavaScript 不行。

<SCRIPT language="VBScript">
Function URLEncoding(vstrIn)
    strReturn = ""
    For i = 1 To Len(vstrIn)
        ThisChr = Mid(vstrIn, i, 1)
        If Abs(Asc(ThisChr)) < &HFF Then
            strReturn = strReturn & ThisChr
        Else
            innerCode = Asc(ThisChr)
            If innerCode < 0 Then
                innerCode = innerCode + &H10000
            End If
            Hight8 = (innerCode And &HFF00) \ &HFF
            Low8 = innerCode And &HFF
            strReturn = strReturn & "%" & Hex(Hight8) & "%" & Hex(Low8)
        End If
    Next
    URLEncoding = strReturn
End Function

Function bytes2BSTR(vIn)
    strReturn = ""
    For i = 1 To LenB(vIn)
        ThisCharCode = AscB(MidB(vIn, i, 1))
        If ThisCharCode < &H80 then
            strReturn = strReturn & Chr(ThisCharCode)
        Else
            NextCharCode = AscB(MidB(vIn, i + 1, 1))
            strReturn = strReturn & Chr(CLng(ThisCharCode) * &H100 + CInt(NextCharCode))
            i = i + 1
        End If
    Next
    bytes2BSTR = strReturn
End Function

strA = URLEncoding("submit1=Submit&text1=中文")
oReq = CreateObject("MSXML2.XMLHTTP")
oReq.open "POST", "https://ServerName/VDir/TstResult.ASP", false
oReq.setRequestHeader "Content-Length", Len(strA)
oReq.setRequestHeader "CONTENT-TYPE", "application/x-www-form-urlencoded"
oReq.send strA
alert bytes2BSTR(oReq.responseBody)
</SCRIPT>

試試這段,中文便會正常顯示。

關於 VBScript 的 byte 陣列

順帶一提,byte 型別在 VBScript 裡的行為相當古怪:對它呼叫 VarType 會得到 8209(vbArray + vbByte),用 LBound、UBound 取得到上下界,卻無法以 name(i) 的形式取值,讓人一度以為 Script 根本無法處理這種型別。上面 bytes2BSTR 的寫法,其實是把它當字串在處理——用 LenB、MidB 一類的函式逐位元組取出。這個發現純屬意外:原本傳入的是 responseText,只是想逐位元組看看內容長什麼樣,臨時起意改成 responseBody,問題就迎刃而解了。

測試環境

以上程式在 MSXML Parser 3 Release 搭配 VBScript 5.5 的環境下測試通過。使用較舊版本 Script 引擎的讀者,建議自行驗證一次。

另外值得一提的是,以往總覺得 JavaScript 略勝 VBScript 一籌,因此曾想徹底丟掉 VBScript、伺服器端與用戶端一律採用 JavaScript。從這個 byte 陣列的案例看來,這未必是好主意——某些底層操作仍是非 VBScript 莫屬。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved