DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
XML進階學習筆記(6):XML資料庫與ADO的資料輸出實作
編輯:XML詳解     

這一篇筆記把話題從語法轉向工程實務:XML資料庫該具備哪些能力,以及如何用ASP與ADO把關聯式資料庫的內容輸出成XML文檔。

關聯式資料庫與物件導向資料庫的差異

在關聯式資料庫中,資料就只是資料,本身不攜帶任何層次結構資訊;而物件導向資料庫把資料視為物件,資料作為一個整體存在,同時包含屬性與方法,並能體現資料之間的繼承關係。這個差異,正是XML資料庫想要彌補的落差。

一個XML資料庫該具備什麼

  • 以DTD或Schema定義模式:不必另外做資料庫設計,直接依DTD/Schema的層次結構進行定位與查詢,並可透過元素名稱與屬性存取節點
  • 支援DOM與SAX:能進行事件驅動的XML處理
  • 內建XML語法分析器:可解析文檔資料,並對資料庫中的元素直接定位操作
  • 提供標準XML查詢語言:套用樣式模式後,可輸出多種格式的XML文檔
  • 能處理大型資料集:可對置標文本的結構與內容建立索引
  • 提供開發工具包:支援DOM、SAX、JavaScript等
  • 具備一致性機制:例如以行級或頁級的共享鎖、排他鎖,在多使用者並發讀寫時維持資料有效性
  • 支援OLAP與資料倉庫等高階應用

用ASP輸出XML:兩種做法

第一種是透過程式物件模型動態組出XML文檔。先建立XMLDOM物件與根節點,再逐筆把資料庫記錄轉成子節點:

<% @language = "VBScript" %>
<% Response.ContentType = "text/xml" %>
<?xml version="1.0" encoding="GB2312"?>
<%
' 動態建構XML文檔
set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")
set root = xmlDoc.createNode("element", "聯絡人列表", "")
xmlDoc.appendChild(root)

' 查詢資料庫
sqlStr = "select * from clientList"
set cConn = Server.CreateObject("ADODB.Connection")
cConn.Open "CLIENTS", "sa", ""
set rsData = cConn.Execute(sqlStr)
rsData.MoveFirst()

while (not rsData.EOF)
  ' 建構聯絡人子節點
  set tmpNode = xmlDoc.createNode("element", "聯絡人", "")
  xmlDoc.documentElement.appendChild(tmpNode)

  ' 依欄位建構姓名、ID、公司、Email子節點
  for i = 0 to rsData.Fields.Count - 1
    set childNode = xmlDoc.createNode("element", rsData.Fields(i).Name, "")
    childNode.text = rsData.Fields(i)
    tmpNode.appendChild(childNode)
  next
  rsData.MoveNext()
wend
Response.Write(xmlDoc.xml)
%>

第二種更直觀:直接把XML標籤寫在ASP裡,用 <%= %> 把欄位值填進去。

<% Response.ContentType = "text/xml" %>
<?xml version="1.0" encoding="GB2312"?>
<聯絡人列表>
<%
  Set cConn = Server.CreateObject("ADODB.Connection")
  cConn.Open "CLIENTS", "sa", ""
  Set rsData = cConn.Execute("select * from clientList")
  do while not rsData.Eof
%>
  <聯絡人>
    <姓名><%= rsData("Name") %></姓名>
    <ID><%= rsData("ID") %></ID>
    <公司><%= rsData("Company") %></公司>
    <Email><%= rsData("Email") %></Email>
  </聯絡人>
<%
  rsData.MoveNext
  Loop
  rsData.Close
  Set rsData = nothing
%>
</聯絡人列表>

最終產出的文檔大致如下:

<?xml version = "1.0" encoding="GB2312" standalone = "no"?>
<聯絡人列表>
  <聯絡人>
    <姓名>張三</姓名>
    <ID>1</ID>
    <公司>A公司</公司>
    <EMAIL>zhang@aaa.com</EMAIL>
  </聯絡人>
  <聯絡人>
    <姓名>李四</姓名>
    <ID>2</ID>
    <公司>B公司</公司>
    <EMAIL>li@bbb.org</EMAIL>
  </聯絡人>
</聯絡人列表>

但這樣繞了遠路

仔細想想會發現一個矛盾:資料既然已經存在資料庫裡,為什麼還要大費周章重新定義一遍文檔結構?XML的自描述性又體現在哪裡?

為了解決這個問題,微軟擴充了ADO技術以提供更好的XML支援。結果是:可以直接依資料庫表的內在結構輸出XML文檔,格式符合預設的DTD定義。以下是用Visual Basic 6.0寫的實例:

' 宣告連接與結果集
Dim cConn As ADODB.Connection
Dim rsData As ADODB.Recordset

Private Sub Form_Load()
  ' 連接資料庫
  Dim query As String
  Set cConn = New ADODB.Connection
  cConn.ConnectionString = "DSN=nwind;UID=sa;PWD=;"
  cConn.Open

  ' 執行查詢
  query = "Select * FROM clientList"
  Set rsData = cConn.Execute(query)

  ' 把結果集存成檔案
  On Error Resume Next
  Kill ("recordset.XML")
  rsData.Save "output.xml", adPersistXML
End Sub

執行後產生的output.xml,實際上是一份內嵌XML Schema的XML實例文檔。主元素是 <rs:data>,命名空間rs由 xmlns:rs='urn:schemas-microsoft-com:rowset' 定義;資料庫查詢返回的每一筆記錄,都是 <rs:data> 的子元素,以 <z:row> 表示。這些 <z:row> 其實是空元素,資訊全以屬性的形式呈現,屬性名稱直接來自資料庫欄位。

<xml xmlns:s='uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882'
     xmlns:dt='uuid:C2F41010-65B3-11d1-A29F-00AA00C14882'
     xmlns:rs='urn:schemas-microsoft-com:rowset'
     xmlns:z='#RowsetSchema'>
  <s:Schema id='RowsetSchema'>
    <s:ElementType name='row' content='eltOnly'>
      <s:attribute type='Name'/>
      <s:attribute type='ID'/>
      <s:attribute type='Company'/>
      <s:attribute type='Email'/>
      <s:extends type='rs:rowbase'/>
    </s:ElementType>
    <s:AttributeType name='Name' rs:number='1' rs:nullable='true' rs:write='true'>
      <s:datatype dt:type='string' dt:maxLength='10'/>
    </s:AttributeType>
    <s:AttributeType name='ID' rs:number='2' rs:nullable='true' rs:write='true'>
      <s:datatype dt:type='int'/>
    </s:AttributeType>
    ……
  </s:Schema>
  <rs:data>
    <z:row Name='張三' ID='1' Company='A公司' Email='zhang@aaa.com'/>
    <z:row Name='李四' ID='2' Company='B公司' Email='li@bbb.org'/>
  </rs:data>
</xml>

其中 <s:Schema id='RowsetSchema'> 這一段,定義了 <row> 元素的組織結構與規則,讓這份輸出檔具備自我描述能力——這才真正回到了XML自描述的原點。

ADO的存檔與直接輸出

ADO提供了文檔保存功能,ASP可以把資料庫結果集存成XML檔案,這些檔案經XSL樣式化後可直接在瀏覽器顯示,也可以傳給其他系統重複利用。

更進一步的是,ADO 2.5與IIS 5.0支援把查詢結果直接轉成XML輸出到瀏覽器,不必先落地成檔案:

<%
Set rsData = Server.CreateObject("ADODB.Recordset")
Response.ContentType = "text/xml"
rsData.Open "select * from clientList", _
           "File Name=" & Server.MapPath("ado.udl")
rsData.Save Response, adPersistXML
rsData.Close
Set cConn = nothing
%>

這段程式把結果集直接存進Response物件,XML就即時流入Client端,省掉了中間檔案與額外的讀取步驟。對需要即時供數的Web場景來說,這個模式相當實用。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved