XSLT 沒有內建的位元運算函式,遇到需要處理 OR、AND、XOR 這類運算時得自己想辦法。由於 XPath 1.0 提供了 floor()、mod、div 這些算術工具,我們其實可以逐位元拆解,用純 XSLT 把三種運算都實作出來。
核心手法一致:從最高位(2147483648,也就是 2 的 31 次方)開始,用 floor(value div bitval) 取出該位的 0 或 1,依運算規則決定這一位的結果,再把 value 對 bitval 取餘數,然後遞迴處理下一位,直到 bitval 降為 1 為止。累積值透過 accum 參數層層往上帶。
需要留意的是,這組模板只適用於無號整數(unsigned int),負數的處理不在其範圍內。
<!-- ======================================================== -->
<!-- Function: BooleanOR(<value1>,<value2>) => number -->
<!-- Parameters:- -->
<!-- <value1> - the first number to be ORed -->
<!-- <value2> - the second number to be ORed -->
<!-- NB. Only works with unsigned ints! -->
<!-- ======================================================== -->
<xsl:template name="BooleanOR">
<xsl:param name="value1" select="number(0)"/>
<xsl:param name="value2" select="number(0)"/>
<!-- recurse parameters -->
<xsl:param name="bitval" select="number(2147483648)"/>
<xsl:param name="accum" select="number(0)"/>
<!-- calc bits present on values -->
<xsl:variable name="bit1" select="floor($value1 div $bitval)"/>
<xsl:variable name="bit2" select="floor($value2 div $bitval)"/>
<!-- do the OR on the bits -->
<xsl:variable name="thisbit">
<xsl:choose>
<xsl:when test="($bit1 != 0) or ($bit2 != 0)"><xsl:value-of select="$bitval"/></xsl:when>
<xsl:otherwise>0</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<!-- if last recurse then output the value -->
<xsl:choose>
<xsl:when test="$bitval = 1"><xsl:value-of select="$accum + $thisbit"/></xsl:when>
<xsl:otherwise>
<!-- recurse required -->
<xsl:call-template name="BooleanOR">
<xsl:with-param name="value1" select="$value1 mod $bitval"/>
<xsl:with-param name="value2" select="$value2 mod $bitval"/>
<xsl:with-param name="bitval" select="$bitval div 2"/>
<xsl:with-param name="accum" select="$accum + $thisbit"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- ======================================================== -->
<!-- Function: BooleanAND(<value1>,<value2>) => number -->
<!-- Parameters:- -->
<!-- <value1> - the first number to be ANDed -->
<!-- <value2> - the second number to be ANDed -->
<!-- NB. Only works with unsigned ints! -->
<!-- ======================================================== -->
<xsl:template name="BooleanAND">
<xsl:param name="value1" select="number(0)"/>
<xsl:param name="value2" select="number(0)"/>
<!-- recurse parameters -->
<xsl:param name="bitval" select="number(2147483648)"/>
<xsl:param name="accum" select="number(0)"/>
<!-- calc bits present on values -->
<xsl:variable name="bit1" select="floor($value1 div $bitval)"/>
<xsl:variable name="bit2" select="floor($value2 div $bitval)"/>
<!-- do the AND on the bits -->
<xsl:variable name="thisbit">
<xsl:choose>
<xsl:when test="($bit1 != 0) and ($bit2 != 0)"><xsl:value-of select="$bitval"/></xsl:when>
<xsl:otherwise>0</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<!-- if last recurse then output the value -->
<xsl:choose>
<xsl:when test="$bitval = 1"><xsl:value-of select="$accum + $thisbit"/></xsl:when>
<xsl:otherwise>
<!-- recurse required -->
<xsl:call-template name="BooleanAND">
<xsl:with-param name="value1" select="$value1 mod $bitval"/>
<xsl:with-param name="value2" select="$value2 mod $bitval"/>
<xsl:with-param name="bitval" select="$bitval div 2"/>
<xsl:with-param name="accum" select="$accum + $thisbit"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- ======================================================== -->
<!-- Function: BooleanXOR(<value1>,<value2>) => number -->
<!-- Parameters:- -->
<!-- <value1> - the first number to be XORed -->
<!-- <value2> - the second number to be XORed -->
<!-- NB. Only works with unsigned ints! -->
<!-- ======================================================== -->
<xsl:template name="BooleanXOR">
<xsl:param name="value1" select="number(0)"/>
<xsl:param name="value2" select="number(0)"/>
<!-- recurse parameters -->
<xsl:param name="bitval" select="number(2147483648)"/>
<xsl:param name="accum" select="number(0)"/>
<!-- calc bits present on values -->
<xsl:variable name="bit1" select="floor($value1 div $bitval)"/>
<xsl:variable name="bit2" select="floor($value2 div $bitval)"/>
<!-- do the XOR on the bits -->
<xsl:variable name="thisbit">
<xsl:choose>
<xsl:when test="(($bit1 != 0) and ($bit2 = 0)) or (($bit1 = 0) and ($bit2 != 0))">
<xsl:value-of select="$bitval"/>
</xsl:when>
<xsl:otherwise>0</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<!-- if last recurse then output the value -->
<xsl:choose>
<xsl:when test="$bitval = 1"><xsl:value-of select="$accum + $thisbit"/></xsl:when>
<xsl:otherwise>
<!-- recurse required -->
<xsl:call-template name="BooleanXOR">
<xsl:with-param name="value1" select="$value1 mod $bitval"/>
<xsl:with-param name="value2" select="$value2 mod $bitval"/>
<xsl:with-param name="bitval" select="$bitval div 2"/>
<xsl:with-param name="accum" select="$accum + $thisbit"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
把三份模板並排來看會發現,它們的骨架完全相同,唯一不同的是決定 thisbit 的那個 xsl:when 條件:
OR:兩位中只要有一位是 1,結果就是 1。
AND:兩位必須同時是 1,結果才是 1。
XOR:兩位狀態不同時才為 1,也就是「有且只有一位是 1」。
理解這一點之後,這組模板就不必死背。要擴充新的運算(例如 NAND、NOR),只需照著同一個遞迴骨架換掉條件即可。
另外提醒一個實作上的細節:遞迴終止條件設在 $bitval = 1,也就是處理完最低位才輸出結果,因此 accum 的累加必須發生在每一層遞迴的呼叫參數裡,而不能等到回傳後再加——這正是這類「尾端遞迴」在宣告式語言中累積狀態的標準手法。