Perl 的普及與網際網路的蓬勃發展息息相關。Perl 強大的功能與易於擴充的特性,使它成為開發 CGI 應用最自然的選擇,並迅速躍升為 CGI 腳本的首選語言。CGI 本身並非十全十美,但由於廣受眾多開發商青睞,其應用至今依然十分廣泛,近期內也看不出任何「退休」的跡象。
一個典型的 CGI::XMLApplication 腳本包含三部分:一個極小的、提供應用程式存取支援的可執行腳本;一個實作各種管理者方法的邏輯模組;以及依應用狀態而定、可能有一或多個的 XSLT 樣式表——它能將模組回傳的結果轉化成瀏覽器可向用戶顯示的格式。
以下透過實例,簡要介紹 CGI::XMLApplication 的應用。
CGI::XMLApplication 假定,參與一個專案設計與開發的人員會使用 XSLT 樣式表來分離應用的邏輯與表示,這種分離既直接又不會對專案造成負擔。開發者只要讓 setStylesheet 回傳符合當前應用狀態的 XSLT 樣式表位置即可,而 DOM 樹的轉換、XSLT 參數向轉換引擎的傳遞、轉換後內容向瀏覽器的傳輸,對用戶而言都是透明的。
為了凸顯這種分離,我們的第一個例子並不是傳統意義上的 Web 應用,而是一個通用的 XSLT 網關。它可以被加入伺服器的 CGI-bin 中,把整個 XML 內容的目錄樹轉化成符合請求的瀏覽器格式,而這一切對用戶、樣式表與文檔作者而言也都是透明的。
第一步,是建立連接客戶端請求與應用的 CGI 腳本。我們希望 XML 文檔能方便地透過 URL 瀏覽,並讓建立這些文檔之間的超連結變得直觀。因此,我們將建立一個沒有副檔名的 CGI 腳本,把它當作 URL 路徑中的一個節點,節點右側的所有內容都將在包含 XML 內容的虛擬文檔環境中加以解讀。在這種情況下,我們把這個 CGI 稱為「樣式表選擇器」。
use strict; use lib '/path/to/secure/webapp/libs'; use XSLGateway; use CGI qw(:standard); my $q = CGI->new(); my %context = (); my $gateway_name = 'stylechooser';
在載入合適的模組並設定一些全域有效的變數後,我們開始向傳給應用邏輯類別的 %context 中加入一些欄位。在這個應用中,我們只傳輸指向腳本檔案路徑右側的 URL(REQUEST 條目),以及包含儲存在查詢參數 style 中資料的 STYLE 關鍵字。
$context{REQUEST} = $q->url(-path => 1);
$context{REQUEST} =~ s/^$gateway_name\/?//;
$context{REQUEST} ||= 'index.xml';
$context{STYLE} = $q->param('style') if $q->param('style');
最後,我們建立 XSLGateway 邏輯類別的一個執行個體,並呼叫其 run 方法來處理請求,把 %context 作為唯一的參數。
my $app = XSLGateway->new(); $app->run(%context);
CGI 腳本至此便完成了。接下來,我們建立承擔大部分工作的 XSLGateway 模組:
package XSLGateway; use strict; use vars qw(@ISA); use CGI::XMLApplication; use XML::LibXML; @ISA = qw(CGI::XMLApplication);
如簡介所述,CGI::XMLApplication 透過事件呼叫運作:應用程式類別中某個方法的執行,取決於某個指定欄位的輸入(通常用來提交表單的按鈕名稱)。必須實作的呼叫方法有兩個:selectStylesheet 與 requestDOM。
selectStylesheet 回傳相關的 XSLT 樣式表之完整檔案系統路徑。為簡單起見,我們假設樣式表都存放在同一個目錄中;我們也可以透過 $context->{STYLE} 欄位提供其他樣式表,以增加系統的靈活性。
sub selectStylesheet {
my $self = shift;
my $context = shift;
my $style = $context->{STYLE} || 'default';
my $style_path = '/opt/www/htdocs/stylesheets/';
return $style_path . $style . '.xsl';
}
下一步,我們需要建立 requestDOM 方法,它會回傳被傳輸的 XML 文檔之 XML::LibXML DOM 表達式。由於我們的網關只適用於靜態檔案,因此需要用 XML::LibXML 對文檔進行解析,並回傳結果樹。
sub requestDOM {
my $self = shift;
my $context = shift;
my $xml_file = $context->{REQUEST} || 'index.xml';
my $doc_path = '/opt/www/htdocs/xmldocs/';
my $requested_doc = $doc_path . $xml_file;
my $parser = XML::LibXML->new;
my $doc = $parser->parse_file($requested_doc);
return $doc;
}
至此,我們的 CGI 腳本已能安全地在伺服器的 cgi-bin 目錄中運行。只要在適當的目錄中上載一些 XML 文檔與一兩個 XSLT 樣式表,就能開始檢驗成果。對 https://localhost/cgi-bin/stylechooser/mydocs/somefile.xml 的請求,會使伺服器從 /opt/www/htdocs/xmldocs/ 目錄中選取 mydocs/somefile.xml 檔,使用 /opt/www/htdocs/stylesheets/ 中的 default.xsl 樣式表對它進行轉換,再傳給客戶。
若有需要,我們可以擴充這個基本框架,例如:在樣式表選擇 CGI 腳本中加些查找元件來挑選合適的樣式表、設定或讀取 HTTP cookies,為網站增添變化。
這個例子裡,我們將用 CGI::XMLApplication 打造一個簡化的 Web 應用——購物系統。
與上例相同,這個應用中與 CGI-BIN 相關的部分仍然極少。我們要做的,不過是初始化 CustomerOrder 應用類別並呼叫它的 run() 方法。這次,我們把 CGI.pm 中的 Vars 作為 %context 的 PARAMS 欄位:
use strict;
use CGI qw(:standard);
use lib '/path/to/secure/webapp/libs';
use CustomerOrder;
my $q = CGI->new();
my %context = ();
$context{PARAMS} = $q->Vars;
my $app = CustomerOrder->new();
$app->run(%context);
這裡我們假設該應用的產品資訊儲存在關聯式資料庫中,且產品清單不算太長,不至於需要好幾個畫面才能顯示完整。用戶操作流程包含:輸入訂購產品數量的主要輸入畫面、顯示訂購單內容與所選物品總價格的確認畫面,以及顯示訂單已處理的提示畫面。為簡單起見,這裡未涉及送貨與財務資料的輸入。
package CustomerOrder; use strict; use vars qw(@ISA); use CGI::XMLApplication; use XML::LibXML::SAX::Builder; use XML::Generator::DBI; use DBI; @ISA = qw(CGI::XMLApplication);
在載入必要的模組並定義從 CGI::XMLApplication 繼承的類別後,我們開始建立與各種狀態相關的事件呼叫。首先,必須透過建立 registerEvents() 方法來註冊這些事件。本例中,我們註冊 order_confirm 與 order_send 兩個方法,它們會設定 %context 中的 SCREENSTYLE 欄位;稍後,我們將藉此決定在顯示客戶端資料時,該採用三個 XSLT 樣式表中的哪一個。
需要注意的是,這些事件會被映射到實作它們的實際子程序,命名規則為 event_<事件名>,例如 order_confirm 事件由 event_order_confirm 執行。此外,各事件的選擇是由 CGI::XMLApplication 依其查找與註冊事件同名的表單參數之能力來進行的。舉例來說,要執行 order_confirm 事件,表單元件中必須包含一個提交非空值、名為 order_confirm 的表單欄位。
# 事件的註冊與事件呼叫
sub registerEvents {
return qw( order_confirm order_send );
}
sub event_order_confirm {
my ($self, $context) = @_;
$context->{SCREENSTYLE} = 'order_confirm.xsl';
}
sub event_order_send {
my ($self, $context) = @_;
$context->{SCREENSTYLE} = 'order_send.xsl';
}
若沒有請求執行其他事件,則預設執行 event_default。本例中,我們只用它把 SCREENSTYLE 欄位設為合適的值。
sub event_default {
my ($self, $context) = @_;
$context->{SCREENSTYLE} = 'order_default.xsl';
}
每次請求都會執行 event_init 方法,而且總是在其他方法之前執行,這使它非常適合用來初始化應用中被其他事件使用的部分。本例中,我們用它回傳透過 fetch_recordset() 方法從資料庫取得的最初 DOM 樹。
sub event_init {
my ($self, $context) = @_;
$context->{DOMTREE} = $self->fetch_recordset();
}
狀態處理方法完成後,我們需要執行必要的 selectStylesheet 與 requestDOM 方法。
與第一個例子一樣,我們假設所有應用的樣式表都存放在伺服器上同一個目錄中,我們要做的,就是回傳 $context->{SCREENSTYLE} 所指定的路徑並附加到末尾。
# app config and helpers
sub selectStylesheet {
my ($self, $context) = @_;
my $style = $context->{SCREENSTYLE};
my $style_path = '/opt/www/htdocs/stylesheets/cart/';
return $style_path . $style;
}
在研究 requestDOM 處理常式之前,我們先仔細看看 fetch_recordset 這個輔助方法。
要記住,我們要做的是從關聯式資料庫中選取所訂購產品的相關資訊,但傳給 XSLT 處理器的資料必須是 DOM 樹。本例中,我們不透過手動程式實作,而是利用 XML::Generator::DBI——它能從執行 SQL SELECT 語句得到的資料中產生 SAX 資料。要建立所需的 DOM 樹,只需建立 XML::LibXML::SAX::Builder(它從 SAX 事件中建立 XML::LibXML DOM 樹)的執行個體即可。
sub fetch_recordset {
my $self = shift;
my $sql = 'select id, name, price from products';
my $dbh = DBI->connect('dbi:Oracle:webclients', 'chico', 'sWordfish') || die "database connection couldn't be initialized: $DBI::errstr \n";
my $builder = XML::LibXML::SAX::Builder->new();
my $gen = XML::Generator::DBI->new(Handler => $builder, dbh => $dbh, RootElement => 'document', QueryElement => 'productlist', RowElement => 'product');
my $dom = $gen->execute($sql) || die "Error Building DOM Tree\n";
return $dom;
}
fetch_recordset 方法完成了一項很重要的任務,但它回傳的 DOM 樹只包含我們想傳給客戶的一部分資訊,我們還得擷取用戶輸入的產品數量,並提供一個訂購產品的總計。
sub requestDOM {
my ($self, $context) = @_;
my $root = $context->{DOMTREE}->getDocumentElement();
my $grand_total = '0';
為了把當前的訂貨數量作為更大文檔的一部分,我們將遍歷所有產品元素,並在每一行中加入 <quantity> 與 <item-total> 子元素,其值可從 $context->{PARAMS} 欄位取得。
foreach my $row ($root->findnodes('/document/productlist/product')) {
my $id = $row->findvalue('id');
my $cost = $row->findvalue('price');
my $quantity = $context->{PARAMS}->{$id} || '0';
my $item_total = $quantity * $cost;
$grand_total += $item_total;
# add the order quantity and item totals to the tree.
$row->appendTextChild('quantity', $quantity);
$row->appendTextChild('item-total', $item_total);
}
最後,我們加入一些關於訂單的中繼資訊,方法是為根元素加入一個 <instance-info> 元素,其中含有當前所選貨物的總價值。
$grand_total ||= '0.00';
my $info = XML::LibXML::Element->new('instance-info');
$info->appendTextChild('order-total', $grand_total);
$root->appendChild($info);
return $context->{DOMTREE};
}
細心的讀者可能已注意到,我們這個非常簡單的應用,在 order_send 方法中並未做任何實際的事。決定如何處理這些資料,正是產品訂購應用中最貼近具體購物網站的部分。
CGI::XMLApplication 在 CGI 腳本的程式設計中,提供了一種清晰、模組化地隔離系統內容與表示的方法,單憑這一點,就值得我們對它加以研究。此外,它還能讓我們避免糾纏於細枝末節,得以專心解決主要問題。