DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
實作分享:用 WML 加 ASP 做手機端企業資料查詢
編輯:XML詳解     

這個範例的起因很實際:工作上要查企業註冊資料的人太多,於是在網站上加了查詢功能,後來有人反映手邊沒有電腦——但手機總該有吧。既然要隨時隨地能查,索性動手做一個 WAP 查詢服務。以下三個頁面全部用記事本寫成。

資料庫結構:庫名 data.mdb,表名 info,欄位包含 id、企業名稱、住所、法定代表人、註冊資本、企業類型、經營範圍、成立日期等。

一、輸入頁 hello.asp

<%@ Language=VBScript %>
<% Response.ContentType = "text/vnd.wap.wml" %>
<?xml version="1.0" encoding="gb2312"?>
<!DOCTYPE wml PUBLIC "-//WAPFORUM//DTD WML 1.1//EN" "https://www.wapforum.org/DTD/wml_1.1.xml">
<wml>
<card id="qycx" title="上饒工商信息網">
<p>
請輸入查詢資料<input name="qycx" type="text" maxlength="16"/>
<anchor title="確定">確定
<go href="qycx.asp" method="post">
<postfield name="qycx" value="$(qycx:esc)"/>
</go>
</anchor>
<br/><br/>
上饒工商信息網
</p>
</card>
</wml>

二、查詢結果頁 qycx.asp

<%@ Language=VBScript %>
<% Response.ContentType = "text/vnd.wap.wml" %>
<?xml version="1.0" encoding="gb2312"?>
<!DOCTYPE wml PUBLIC "-//WAPFORUM//DTD WML 1.1//EN" "https://www.wapforum.org/DTD/wml_1.1.xml">
<wml>
<card id="qycx2" title="上饒工商信息網">
<p>
<%
qycx = Request.Form("qycx")
cx = "企業名稱 like '%" & qycx & "%'"
Set conn = Server.CreateObject("adodb.connection")
conn.open "driver={microsoft Access driver (*.mdb)};dbq=" & Server.MapPath("qycx.mdb")
sql = "select * from info where " & cx
Set rs = Server.CreateObject("adodb.recordset")
rs.open sql, conn, 1, 1
Do While Not rs.eof
%>
<%
qymc = rs("企業名稱")
id = rs("id")
%>
<a href="qycx2.asp?id=<% = id %>"><% = qymc %></a>
<br/>
<%
rs.movenext
Loop
rs.close
%>
<br/><br/>
上饒工商信息網
</p>
</card>
</wml>

這一頁的邏輯是:依 hello.asp 傳來的關鍵字,撈出所有企業名稱含有該字的記錄,以清單列出企業全稱避免重複,點擊後帶著 id 進入第三頁看詳細資料。

這裡有個值得記取的教訓。一開始我把「企業名稱」當作查詢後續頁面的參數直接放進網址,結果中文在 URL 傳遞時出現編碼問題,折騰了大半天才想到改用 id 當查詢鍵值。中文參數要嘛先做編碼轉換,要嘛就乾脆用數值型主鍵,後者遠比前者省心。

另外,把使用者輸入直接串進 SQL 陳述式是有風險的做法,正式環境應改用參數化查詢,並限制輸入長度,避免 SQL 注入。

三、詳細資料頁 qycx2.asp

<%@ Language=VBScript %>
<% Response.ContentType = "text/vnd.wap.wml" %>
<?xml version="1.0" encoding="gb2312"?>
<!DOCTYPE wml PUBLIC "-//WAPFORUM//DTD WML 1.1//EN" "https://www.wapforum.org/DTD/wml_1.1.xml">
<%
Set conn = Server.CreateObject("adodb.connection")
conn.open "driver={microsoft Access driver (*.mdb)};dbq=" & Server.MapPath("qycx.mdb")
%>
<wml>
<card id="qycx3" title="上饒工商信息網">
<p>
<%
name = Request.QueryString("id")
sql = "select * from info where id=" & name
Set rs = Server.CreateObject("adodb.recordset")
rs.open sql, conn, 1, 1
Do While Not rs.eof
%>
<% = rs("企業名稱") %><br/>
<% = rs("住所") %><br/>
<% = rs("法定代表人") %><br/>
註冊資本: <% If Left(rs("註冊資本"), 1) = "." Then Response.Write "0" %><% = rs("註冊資本") %>萬元<br/>
<% = rs("企業類型") %><br/>
<% = rs("經營範圍") %><br/>
註冊日期: <% = rs("成立日期") %><br/>
<%
rs.movenext
Loop
rs.close
%>
<br/><br/>
上饒工商信息網 - End
<br/>
<a href="hello.asp">返回</a>
</p>
</card>
</wml>

三個頁面串起來,手機端就能完成「輸入關鍵字 → 挑選企業 → 瀏覽詳細資料」的完整流程。註冊資本那一小段判斷,是為了處理資料庫中以小數開頭的數值(例如 .5),補上前面的 0 才不會顯示成「.5萬元」。

整體來說,WML 加 ASP 的組合在當時足以勝任輕量查詢服務;若今天要重做,前端會改用回應式網頁,後端也會換成具備參數化查詢能力的框架,但分頁切分與小螢幕資訊密度的思考方式,其實和當年並沒有太大不同。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved