时至今日,資料庫儼然成了網站的核心。可以說,缺少對資料的集中管理,就稱不上是一個真正完整的網站。而 ASP 搭配資料庫,更是主流中的主流——使用者登入、討論區、留言板,全都靠它派上用場。從前得動用五十幾個檔案才做得成的事,如今兩個檔案就能搞定。然而,ASP 加資料庫並非完美無缺,特別是在與伺服器頻繁往返這件事上。
舉個例子。依照「ASP + 資料庫」的寫法,我們大可把那位勤奮站長的工作濃縮成兩個檔案:一個資料庫檔,記錄小說的所有章節;一個 ASP 檔,負責讀取資料庫內容。當讀者點擊「下一章」,便能繼續閱讀……乍看之下直觀又便利,卻忽略了一件事:每按一次「下一章」,瀏覽器就會自動去拜訪資料庫一次。因此,當一位有耐心的讀者把整本小說看完,我們的資料庫已經被親近過 49 次了。
那如果是同時有 N 個「49 次」呢?誰還能保證自己的伺服器依旧能從容應對所有請求?尤其是那些提供搜尋、把結果分頁顯示的網站,伺服器不堪重負的現象更值得警惕——因為查詢結果有 N 頁,就意味著讀者想看完所有結果,得連上伺服器 N 次。
如果你現在說「N 次就 N 次吧,我不在乎」,那建議你立刻按下瀏覽器的「上一頁」,因為接下來要談的內容恐怕不合你胃口。但若你也希望讓自己的資料庫程式做到「N 頁記錄、一次互動」,那就歡迎繼續看下去,我們將一同探討 XML 與資料庫的整合運用。
其實,XML 並不像許多人想像的那樣只是虛有其名。我不知道你是否也這麼認為,但網路上確實很難見到真正把 XML 用起來的網站,這是事實。以下我列舉幾個非 XML 莫辦的應用情境,希望能藉此證明 XML 的實用與強大:
1. 一個 XML 檔 + 一個普通 HTML 檔 = 49 章小說分章顯示
適用於那些不支援 ASP 的普通主機空間。這種情況下,XML 完全取代了資料庫,很經典地實現了資料與排版的徹底分離,XML 與 HTML 各司其職、互不干擾。
2. 一個 XML 檔 + 一到 N 個 ASP 檔 = 留言板/論壇
適用於那些停用 FileSystemObject 檔案元件與資料庫元件的 ASP 空間。不靠檔案存取、也不用資料庫,光用 XML 一樣能做留言板與論壇,並實現資料庫的所有功能。
3. 一個資料庫 + 一個內嵌 XML 的 ASP 檔 = 「N 頁記錄、一次互動」
這幾種技法都體現了 XML 的精髓。特別是第二種,XML 充分證明了自身優勢——既具備資料庫的強大,又擁有純文字檔的輕巧。一個 .mdb 檔动辄上百 K,而一個 .xml 檔才幾 K;資料庫檔要修改得借助專門軟體或對應的 ASP 程式,XML 檔則用記事本就能搞定。更教人振奮的是,XML 完全可以拋開檔案存取元件與資料庫元件,實現資料的讀寫,甚至新建檔案。而我們即將談到的「N 頁記錄、一次互動」,更是 XML 對資料庫的全面超越。
先看下面這個 XML 檔:
<?XML version="1.0" encoding="gb2312"?>
<在線播放>
<歌曲>
<歌名>Hello Goodbye</歌名>
<URL>FTP://61.139.37.148/music/songs01/english/beatles/hellogoodbye.mp3</URL>
<演唱者>The Beatles</演唱者>
<歌詞>You say yes, I say no</歌詞>
</歌曲>
<歌曲>
<歌名>Yesterday</歌名>
<URL>https://www.mayia.com/beatlescom/beatles/mp3/mp3/yesterday.mp3</URL>
<演唱者>The Beatles</演唱者>
<歌詞>Yesterday, all my troubles seemed so far away</歌詞>
</歌曲>
</在線播放>
試試看,用記事本編輯這個檔案,存成 songList.xml,再用 IE 開啟。若沒有語法錯誤,瀏覽器就會顯示出 XML 特有的樹狀結構,這便是一份合法的 XML 文件。XML 文件的規則與格式非常自由,若要新建一份,只要一字不改地照抄第一行「<?XML version="1.0" encoding="gb2312"?>」,後面的標籤與文字便可隨意安排,僅需遵守以下幾條規則:
1. 起始標籤與結束標籤必須成對出現,標籤名稱可以重複,但不可交錯嵌套。
2. 標籤命名規則近似 Java/C/C++ 的變數命名,且區分大小寫。
3. 一份文件只能有一個根元素,例如實例中的「<在線播放>」。
4. 保留關鍵字「XML」,標籤不得以這三個字母開頭。
5. 一旦文件違反上述規則,便無法在瀏覽器中正常顯示,也就成了不合法的 XML 文件。
好,既然我們已經知道如何撰寫一份合法的 XML 文件,下一步就來探討如何把 XML 文件嵌入 HTML,並用 VBScript 操作其中的資料。先看這份文件:
<Html>
<head>
<title>用 XML 嵌入 Html</title>
</head>
<body bgcolor="#000000" text="#FFFFFF">
<xml id = "XMLFile">
<在線播放>
<歌曲>
<歌名>Hello Goodbye</歌名>
<URL>FTP://61.139.37.148/music/songs01/english/beatles/hellogoodbye.mp3</URL>
<演唱者>The Beatles</演唱者>
<歌詞>You say yes, I say no</歌詞>
</歌曲>
<歌曲>
<歌名>Yesterday</歌名>
<URL>https://www.mayia.com/beatlescom/beatles/mp3/mp3/yesterday.mp3</URL>
<演唱者>The Beatles</演唱者>
<歌詞>Yesterday, all my troubles seemed so far away</歌詞>
</歌曲>
</在線播放>
</xml>
<script language="VBScript">
set xml = XMLFile.recordset
XML.MoveFirst
document.write "第一條記錄<BR>"
document.write XML("歌名") & "<BR>"
document.write XML("演唱者") & "<BR>"
document.write XML("URL") & "<BR>"
document.write XML("歌詞") & "<BR><br>"
XML.MoveNext
document.write "第二條記錄<BR>"
document.write XML("歌名") & "<BR>"
document.write XML("演唱者") & "<BR>"
document.write XML("URL") & "<BR>"
document.write XML("歌詞") & "<BR>"
</script>
</body>
</Html>
在這份 HTML 中,我們加入一對 <xml></xml> 標記,用來嵌入一份內部 XML 文件。嵌入的 XML 遵循與獨立文件相同的規則,只是省去了聲明部分「<?xml version="1.0" encoding="gb2312"?>」。在 <XML> 標籤裡,我們設定了 ID 為 xmlFile,方便後續腳本存取這個 XML 物件。
「set xml = xmlFile.recordset」這行敘述建立了一個可存取 XML 的資料指標,它與 ASP 中的 RecordSet 物件幾乎如出一轍,方法與屬性也大致相同:
XML.MoveFirst() 移到第一條記錄 XML.MoveNext() 移到下一條 XML.MovePrevious() 移到上一條 XML.MoveLast() 移到最後一條 XML.BOF 指標在第一條記錄之前 XML.EOF 指標在最後一條記錄之後 XML.RecordCount 記錄集總數 XML.AbsolutePosition 指標目前位置 XML.AddNew() 新增一條記錄 XML.Delete() 刪除一條記錄
舉例來說,要顯示某首歌的歌名,只要把指標移到該記錄,再用 XML("歌名") 便能取得 <歌名> 與 </歌名> 之間的文字,十分方便。
了解以上內容後,我們就可以開始真正的減負實作。整體思路如下:
1. 用戶端向伺服器的某個 ASP 程式送出查詢條件。
2. 該 ASP 程式回應並連上資料庫。
3. 資料庫把查詢結果回傳給 ASP 程式。
4. 取得資料後,ASP 將資料格式化為 XML,建立成該頁面的內嵌式 XML 物件。
5. 在用戶端實現 XML 分頁(做法類似資料庫分頁)。
6. 此後無論用戶翻多少頁、看多少遍,都不會再與伺服器發生互動。
更妙的是,就算用戶拔掉網線,也依旧能繼續瀏覽尚未看過的分頁內容。
下面是一個線上播放程式的頁面,由兩個檔案構成:songList.mdb 承載歌曲資訊;songList.asp 負責把資料庫中的資料格式化成 XML。頁面完全載入後,無論點多少次「下一首」,都不會再與伺服器互動。
◆songList.ASP◆
<Html>
<head>
<title>殷亮的線上播放</title>
</head>
<body bgcolor="#000000" text="#FF9900">
<% ''''''''''''''''連接資料庫'''''''''''''''''
set songCon = Server.CreateObject("ADODB.connection")
conPath = Server.MapPath("songList.mdb")
conStr = "DRIVER={Microsoft Access Driver (*.mdb)}; dbq="
songCon.open(conStr & conPath)
set rs = Server.CreateObject("ADODB.Recordset")
rs.open "Select * from songList", songCon, 3, 3
%>
<!--動態生成內嵌式 XML 文件,"在線播放"是根標記-->
<xml id = "XMLFile">
<在線播放>
<%
If not rs.eof then
while not rs.eof
%>
<歌曲>
<歌名><%= trim(rs("song_name")) %></歌名>
<URL><%= trim(rs("song_url")) %></URL>
<演唱者><%= trim(rs("songer")) %></演唱者>
<歌詞><%= trim(rs("song_lyrics")) %></歌詞>
</歌曲>
<%
rs.movenext
wend
End If
%>
</在線播放>
</XML>
<!-- 此處省略 Windows Media Player 物件與版面配置,重點在下方以 XML 指標驅動的腳本 -->
<!-- 用循環初始化下拉列表 -->
<script language="VBScript">
set xml = XMLFile.recordset
XML.MoveFirst
dim num
for num = 0 to XML.RecordCount - 1
document.write("<OPTION value=" & xml("url") & ">" & XML("歌名") & "</OPTION>")
XML.MoveNext
next
XML.MoveFirst
</script>
<!-- 各按鈕的單擊事件 -->
<script language="VBScript">
sub play()
textSonger.value = XML("演唱者")
textSongName.value = XML("歌名")
textURL.value = ""
area.value = XML("歌詞")
player.filename = XML("URL")
if xml.AbsolutePosition = XML.recordcount then
btnNext.disabled = true
else
btnNext.disabled = false
end if
if XML.AbsolutePosition = 1 then
btnPre.disabled = true
else
btnPre.disabled = false
end if
end sub
sub btnPre_onclick
XML.MovePrevious
list.selectedIndex = list.selectedIndex - 1
call play()
end sub
sub btnNext_onclick
XML.MoveNext
list.selectedIndex = list.selectedIndex + 1
call play()
end sub
</script>
</body>
</Html>
現在,你知道該怎麼替伺服器減負了嗎?本文旨在探討與分享,若有疏漏之處,歡迎指正與交流。