DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
用 XSLT 抹除 XML 範例檔中的敏感內容
編輯:XML詳解     

處理 XML 時常會遇到這種尷尬:手上的檔案含敏感資料,而你偏好的 XML 工具出了問題——假設是個 bug。你得向供應商提交一份能重現問題的範例檔,可又不能把原始檔案直接寄出去。難就難在,往往是檔案裡某段特殊標記才觸發了缺陷,因此清理時必須把敏感資料拿掉,同時保留足以說明問題的結構特徵。本文示範如何用一點 XSLT 技巧解決這件事。

方案一:清空內容

清單 1 的樣式表會刪除所有文字節點與屬性值,只留下節點結構的骨架。

清單 1(kill-content.xslt)—清除字元資料的 XSLT 腳本

<?XML version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
 xmlns:xsl="https://www.w3.org/1999/XSL/Transform"
>
 <xsl:template match="node()">
 <xsl:copy>
 <xsl:apply-templates select="@*|node()"/>
 </xsl:copy>
 </xsl:template>
 <xsl:template match="@*">
 <xsl:attribute namespace="{namespace-uri()}" name="{name()}"/>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

第一個模板與許多實用腳本一樣,是個恆等轉換;第二個模板把屬性複製到輸出,但丟掉屬性值;第三個模板清空所有文字節點。其餘節點類型(包含元素)都由第一個模板承接,負責把基本結構抄一份到輸出。清單 2 是待處理的範例檔案。

清單 2(patients.xml)—範例 XML 檔案

<?XML version="1.0" encoding="iso-8859-1"?>
<patients>
 <patient id='ep' admitted="2003-06-10">
 <name>Ezra Pound</name>
 <address>
 <street>45 Usura Place</street>
 <city>Hailey</city>
 <province>ID</province>
 </address>
 <condition>ore infectus</condition>
 </patient>
 <patient id='tse' admitted="2003-06-20">
 <name>Thomas Eliot</name>
 <address>
 <street>3 Prufrock Lane</street>
 <city>Stamford</city>
 <province>CT</province>
 </address>
 <condition>Sartor resartus</condition>
 </patient>
 <patient id="co" admitted="2004-11-15">
 <name>Christopher Okigbo</name>
 <address>
 <street>7 Heaven's Gate</street>
 <city>Idoto</city>
 <province>Anambra</province>
 </address>
 <condition>caeli porta quaerit</condition>
 </patient>
</patients>

把清單 1 的樣式表套到清單 2 的檔案上,會得到類似下面的結果(省略 XML 宣告):

<patients><patient id="" admitted=""><name/><address><street/><city/>...

元素與屬性的基本結構都還在,內容則一掃而空。

方案二:以空白保留長度

如果全部清空顯得太激進,而你希望至少保住各節點的長度資訊,可以改用清單 1 的變體。清單 3 的腳本會以等長但全為空白的內容取代所有字元資料。

清單 3(blank-content.xslt)—將字元資料替換為空白的 XSLT 腳本

<?XML version="1.0" encoding="utf-8"?>
<xsl:transform version="1.0"
 xmlns:xsl="https://www.w3.org/1999/XSL/Transform"
 xmlns:x="https://ns.ogbuji.Net/articles"
>
 <x:wsbuffer xml:space="preserve"> </x:wsbuffer>
 <xsl:variable name="wsbuf" select="string(document('')/*/x:wsbuffer)"/>
 <xsl:template match="node()">
 <xsl:copy>
 <xsl:apply-templates select="@*|node()"/>
 </xsl:copy>
 </xsl:template>
 <xsl:template match="@*">
 <xsl:attribute namespace="{namespace-uri()}" name="{name()}">
 <xsl:value-of select="translate(., ., $wsbuf)"/>
 </xsl:attribute>
 </xsl:template>
 <xsl:template match="text()">
 <xsl:value-of select="translate(., ., $wsbuf)"/>
 </xsl:template>
</xsl:transform>

關鍵是頂層那個擴展元素 x:wsbuffer,它提供了替換時要用的空白字元來源。為了排版方便,範例中只放了一些空格,但你可以在裡頭塞入更多空格——原始資料中每個字元資料節點,都會被換成同樣長度的空白,最大長度就是 x:wsbuffer 的字元數。xml:space 屬性用來阻止 XSLT 處理器把 x:wsbuffer 中的空白壓縮掉。事實上 x:wsbuffer 可以放任何內容,當成字元資料的定點替代文字;若你用的是非空白字元,就不需要 xml:space 屬性了。

變數 wsbuf 透過自參照的 XSLT 文件(document('') 的特殊形式)取得替代文字。轉換其餘部分與清單 1 類似,差別在於它沒有刪除文字,而是用 wsbuf 中相同位置的字元逐一替換。與清單 1 一樣,最終輸出不含任何有意義的內容。想改變結果,直接改 x:wsbuffer 的內容即可。

把清單 3 的腳本套用到清單 2 的 XML,結果如下:

<patients> <patient id=" " admitted=" "> <name> </name>...

結語與限制

本文介紹了兩種做法:在保留 XML 文件基本結構的前提下,刪除或改寫內容以避免敏感資訊外洩。這套技術有其邊界,而限制主要来自 XSLT 本身。

最該留意的一點是:如果你要回報的問題,恰恰與字元資料本身的特性有關(例如處理字元實體時的 bug),那麼經過清理的範例檔就失去了關鍵線索。另外,XSLT 也會一併丟掉 XML 文件中的其他資訊,包括頂層宣告、實體參照與 CDATA 區段。若這些內容對釐清問題至關重要,就不能用 XSLT 來清理檔案。

儘管如此,我在很多情況下靠這兩個腳本就足夠了,所以它們仍值得放進工具箱。如果你想對字元資料做更細緻的控制,搭配 EXSLT 擴展會是下一步的自然選擇。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved