DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
用 XSLT 2.0 產生 SQL:為抽象資料模型打造程式碼生成器(上)
編輯:XML詳解     

假設你是某個 PHP 專案的工程團隊負責人,前置條件都已就緒,初步的資料模型大約有 150 張表。現在該算進度了。若你估計自己每天能寫完並通過單元測試一個資料庫存取類,那就是 150 天;每月工作 20 天的話,等於要花上將近八個月,只為了完成資料存取層。

這顯然不可行,必須找個方法把時間壓下來。用持久層框架?即使它能把工期砍半,也還要四個月。自己寫一套通用類庫?這類庫往往難用、易錯,除錯更是痛苦。

還有一條路:先手寫一兩個範例類,再用程式碼生成器產出其餘部分。最壞的情況下,寫生成器本身要花一個月;但之後所有程式碼的生成只要幾分鐘。更關鍵的是,由於 SQL 結構與存取程式碼都由同一個生成器產出,「兩邊對不上」這類缺陷可以從根上消除。

這個計畫可行嗎?當然。本文就說明怎麼做,並解釋為何這樣產出的應用程式更好維護、更健壯,寫起來也更順手。本系列共兩篇:第 1 部分先談程式碼生成的基本觀念,再動手建構生成器的一部分——為給定的模型產生 SQL;第 2 部分深入 XSL,透過產生 PHP 程式碼的過程把生成器補完。

程式碼生成的基本構想

我們需要一個生成器:吃進資料庫的抽象模型,吐出 SQL 結構與 PHP 資料庫存取類。圖 1 說明了這個流程,也順帶示範了把資料庫程式碼導向其他技術(例如 Java)的可能性。

圖 1. 生成器的基本資訊流

圖 1 中的虛線框(SQL 模型與資料庫存取模型)代表從抽象模型衍生的暫時性模型;點線框(Java)則是另一種可能的目標。

下一個問題是技術選型。生成器可以用 Java、Perl、Python 或 Ruby 撰寫;但既然任務本身不算複雜,用 Velocity、XSLT 這類模板引擎也綽綽有餘。XSLT 2.0 是個很好的起點:它本身就功能強大,還能嵌入 Java 程式碼中進一步擴充。

為什麼選 XSLT 2.0

XSLT 2.0 為想拿它當程式碼生成引擎的人提供了相當寬廣的語言能力。本文就用這些特性建構一個健壯的生成器,從抽象的表定義產出 SQL 與 PHP。

在 XSLT 1.x 中只能做單層轉換,而 XSLT 2.0 允許先建立一個代表「待生成程式碼」的中間模型。這項能力讓生成器更容易理解與維護,也讓它日後能被重新導向到其他目標語言。本文會用到標準第二版中的三個新特性:

  • 函式:現在可以自訂函式。對第一版而言這是重大改進,因為那時只能用樣板語法,寫起來冗長累贅。
  • 中間樹:第一版只能對輸入的 XML 樹操作;2.0 可以在記憶體中建立中間樹,再據此衍生其他模板。
  • 結果文件:單一模板現在能產生多個輸出檔。本文用它同時產出 SQL 檔與各個獨立的 PHP 檔。

建構生成器

先從輸入看起。清單 1 是一個簡單圖書資料庫的表定義。

清單 1. 輸入的抽象表定義

<?XML version="1.0" encoding="UTF-8"?>
<tables>
 <table name="Author">
 <field name="first" type="text"/>
 <field name="last" type="text"/>
 </table>
 <table name="Publisher">
 <field name="name" type="text"/>
 <field name="last" type="text"/>
 </table>
 <table name="Book">
 <field name="name" type="text"/>
 <field name="author" type="id"/>
 <field name="publisher" type="id"/>
 </table>
</tables>

這段 XML 定義了三張表及其欄位:Author(作者)、Publisher(出版商)、Book(圖書)。真實的 PHP 應用輸入自然大得多也複雜得多,但作為起點,這個規模剛好。

你可以寫一個生成器,直接把這份 XML 一次轉成 SQL 與 PHP,但我不建議這樣做——模板會迅速膨脹到難以維護。目前程式碼生成的最佳實踐是采用多級模型,每一級只朝目標前進一步。就像在 Web 服務器上用分層來降低複雜度、提升重用性一樣,多級轉換把單次轉換的複雜度壓了下來。

回頭看圖 1:抽象模型先為 SQL 生成一個模型,再透過資料庫存取模型為 PHP 生成另一個模型。這些模型都存在中間樹裡,之後才用來產生程式碼。圖 2 描繪了生成器中 Author 表的演化過程。

圖 2. 單一 SQL 表的演化

最上方的方框是原本的抽象表模型,中間是從它建出的 SQL 模型,最下方則是最終的 SQL 輸出。可以清楚看到,SQL 模型詳細規定了哪些東西會出現在最終的 SQL 檔裡。程式碼模板的任務,就是把這個 XML 轉成 SQL——如此一來,同一個模型就能為不同資料庫產生程式碼。接著來看 XSL。

產生 SQL

清單 2 是主樣式表的開頭部分。

清單 2. 主生成器樣式表的開頭

<?XML version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="https://www.w3.org/1999/XSL/Transform"
 xmlns:gen="https://www.codegeneration.Net/" version="2.0">
 <!-- Output specifications -->
 <xsl:output method="text"/>
 <xsl:output method="xml" name="debug-XML" indent="yes"/>
 <xsl:output method="text" name="sql" indent="yes"/>
 <!-- SQL Templates -->
 <xsl:include href="gen2-sql.xsl" />
 <xsl:include href="gen2-sql-model.xsl" />
 <xsl:include href="gen2-queries.xsl" />
 <!-- Database Access Templates -->
 <xsl:include href="gen2-dba.xsl" />
 <xsl:include href="gen2-PHP.xsl" />
 <!-- The generator main entry point -->
 <xsl:template match="/">
 <!-- Create the SQL model -->
 <xsl:text>Building SQL model
 </xsl:text>
 <xsl:variable name="sql-model">
 <xsl:call-template name="gen-sql-model">
 <xsl:with-param name="model" select="."/>
 </xsl:call-template>
 </xsl:variable>

 <!-- Dump it out for debugging -->
 <xsl:text>Dumpping SQL model
 </xsl:text>
 <xsl:result-document href="db/gen-tables.xml" format="debug-XML">
 <xsl:copy-of select="$sql-model"/>
 </xsl:result-document>
 <!-- Generate the SQL from the SQL model -->
 <xsl:text>Generating SQL
 </xsl:text>
 <xsl:result-document href="db/gen-tables.sql" format="sql" >
 <xsl:apply-templates mode="sql" select="$sql-model/sql" />
 </xsl:result-document>

腳本中最關鍵的兩處,一是建立 sql-model 變數(用來承載 SQL 模型),二是 result-document 標籤(依該變數內容寫出 SQL 檔)。這兩段正好示範了 XSLT 2.0 的兩項實用改進:用 xsl:variable 建立中間樹,用 xsl:result-document 產生多個輸出檔。

接著看從抽象表模型生成 SQL 模型的模板。清單 3 是 gen-sql-model。

清單 3. SQL 模型生成器

<?XML version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="https://www.w3.org/1999/XSL/Transform"
 xmlns:gen="https://www.codegeneration.Net/" version="2.0">

 <!-- Builds the SQL model from the original data model -->
 <xsl:template name="gen-sql-model">
 <xsl:param name="model"/>
 <sql>
 <xsl:for-each select="$model/tables/table">
 <create name="{lower-case(@name)}"
 primary-key="{concat(lower-case(@name),'_id')}">
 <field name="{concat(lower-case(@name),'_id')}"
 type="{gen:model-type-to-sql('integer')}"/>
 <xsl:for-each select="field">
 <field name="{lower-case(@name)}"
 type="{gen:model-type-to-sql(@type)}"/>
 </xsl:for-each>
 </create>
 </xsl:for-each>
 </sql>
 </xsl:template>
</xsl:stylesheet>

這個模板相當單純:接過來源模型,為 SQL 模型補上幾個新標籤。請留意 gen:model-type-to-sql 的呼叫——那不是標準 XSLT 函式,而是清單 4 中自訂的函式。

清單 4. model-to-SQL-type 轉換函式

<xsl:function name="gen:model-type-to-sql">
 <xsl:param name="type"/>
 <xsl:choose>
 <xsl:when test="$type eq 'text'">TEXT NOT NULL</xsl:when>
 <xsl:when test="$type eq 'id'">INTEGER NOT NULL</xsl:when>
 <xsl:when test="$type eq 'integer'">INTEGER NOT NULL</xsl:when>
 </xsl:choose>
</xsl:function>

能自行定義新的 XPath 函式,是 XSLT 2.0 的新能力。以往只能靠 xsl:call-template 語法,參數一多就變得十分笨重;而把樣板當函式用,還會污染樣板的名稱空間。

產生 SQL 的最後一步,是把 SQL 模型格式化為 SQL,這由清單 5 的兩個模板負責。

清單 5. SQL 生成模板

<!-- Template for SQL create tags -->
 <xsl:template match="create" mode="sql">
DROP TABLE IF EXISTS <xsl:value-of select="@name" />;
CREATE <xsl:value-of select="@name" /> (
<xsl:apply-templates mode="sql" select="field" />
PRIMARY KEY ( <xsl:value-of select="@primary-key" /> )
 );
 </xsl:template>
 <!-- Template for SQL field tags -->
 <xsl:template match="field" mode="sql">
<xsl:value-of select="concat(@name,' ',@type,',')" /><xsl:text>
</xsl:text>
 </xsl:template>

真正需要動手的模板就這些。我有一個對應 SQL 模型中 create 標籤的模板,它用 apply-templates 把子標籤交給第二個模板去格式化。

回顧圖 2 會發現,XML 結構與 SQL 結構相似得驚人:create 標籤裡含幾個欄位標籤,而 SQL 的 CREATE 指令也含幾個欄位定義。讓模型的形狀貼近程式碼的形狀,能大幅簡化模板的撰寫。

結語

本文示範了 XSLT 2.0 的幾項新特性——擴充的語言能力,以及為待生成程式碼建立中間模型的能力——並說明如何藉此打造一個健壯的生成器,從抽象表模型產出 SQL。

第 2 部分將說明如何產生程式碼的 PHP 那一半,讓 Web 服務器具備資料庫存取能力,同時介紹 XSLT 2.0 的其他新特性。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved