DIV CSS 佈局教程網

您现在的位置: DIV+CSS佈局教程網 >> 網頁腳本 >  >> XML學習教程 >> XML詳解
XML DOM 新手入門指南(上):從載入文件到遍歷節點
編輯:XML詳解     

DOM 定義了一套標準命令集,規範解析器應該暴露哪些介面,讓你能在程式中存取 HTML 與 XML 文件的內容。支援 DOM 的 XML 解析器會把文件中的資料取出,並透過一組可程式化的物件呈現出來。本文示範如何在 Microsoft XML Parser(Msxml.dll)暴露 XML DOM 之後,對它進行存取與操作。

先看一份原始 XML

在動手之前,先看看解析器要處理的原始檔案,才能體會它替我們省下多少功夫。以下是含 CD 資料的 cds.xml:

<?xml version="1.0"?>
<!DOCTYPE compactdiscs SYSTEM "cds.dtd">
<compactdiscs>
    <compactdisc>
        <artist type="individual">Frank Sinatra</artist>
        <title numberoftracks="4">In The Wee Small Hours</title>
        <tracks>
            <track>In The Wee Small Hours</track>
            <track>Mood Indigo</track>
            <track>Glad To Be Unhappy</track>
            <track>I Get Along Without You Very Well</track>
        </tracks>
        <price>$12.99</price>
    </compactdisc>
    <compactdisc>
        <artist type="band">The Offspring</artist>
        <title numberoftracks="5">Americana</title>
        <tracks>
            <track>Welcome</track>
            <track>Have You Ever</track>
            <track>Staring At The Sun</track>
            <track>Pretty Fly (For A White Guy)</track>
        </tracks>
        <price>$12.99</price>
    </compactdisc>
</compactdiscs>

第二行參照了一份外部 DTD(文件類型定義)檔案。DTD 定義了某類 XML 文件的佈局與預期內容,解析器可藉此判斷文件是否有效。DTD 只是其中一種做法,另一個越來越受歡迎的替代方案是「XML 結構描述」(XML Schema)——不同於 DTD 自有一套獨特的語法,Schema 直接用 XML 來定義。以下是 cds.dtd 的內容:

<!ELEMENT compactdiscs (compactdisc*)>
<!ELEMENT compactdisc (artist, title, tracks, price)>
<!ENTITY % Type "individual | band">
<!ELEMENT artist (#PCDATA)>
<!ATTLIST artist type (%Type;) #REQUIRED>
<!ELEMENT title (#PCDATA)>
<!ATTLIST title numberoftracks CDATA #REQUIRED>
<!ELEMENT tracks (track*)>
<!ELEMENT price (#PCDATA)>
<!ELEMENT track (#PCDATA)>

DOM 的定義是什麼?

XML 的 DOM 是一個物件模型,用來暴露 XML 文件的內容。W3C 的 DOM Level 1 規格通常定義了 DOM 應該暴露哪些屬性、方法與事件。Microsoft 的實作完整支援 W3C 標準,並額外提供一些讓 XML 操作更便利的特性。

如何取得 DOM 物件

使用 XML DOM 的方式,就是建立 XML 解析器物件的執行實例。微軟透過 Msxml.dll 中的一組標準 COM 介面來暴露 XML DOM,這個 DLL 含有操作 XML 文件所需的類別庫與執行碼。

若是在有指令技能的用戶端程式中(例如 Internet Explorer 裡執行的 VBScript),用 CreateObject 建立解析器物件:

Set objParser = CreateObject("Microsoft.XMLDOM")

若是 ASP 中的 VBScript,則應改用:

Set objParser = Server.CreateObject("Microsoft.XMLDOM")

若使用 Visual Basic,可以透過設定對 MSXML 類別庫的參照來存取 DOM,步驟如下:

◆ 開啟「工程/引用」對話框;
◆ 從可用的 COM 物件清單中選擇 Microsoft XML, v2.0(若找不到,需先取得 MSXML 類別庫);
◆ 接著即可建立解析器物件實例:

Dim xDoc As MSXML.DOMDocument
Set xDoc = New MSXML.DOMDocument

取得 Msxml.dll 有兩種途徑:安裝 Internet Explorer 5.0(MSXML 解析器是其中一個完整元件),或下載可再散發的 Microsoft XML Parser 安裝套件。

如何載入文件

載入 XML 文件的第一步,是建立 DOMDocument 類別的實例:

Dim xDoc As MSXML.DOMDocument
Set xDoc = New MSXML.DOMDocument

取得有效參照後,用 Load 方法開啟檔案。MSXML 解析器可以從本機磁碟載入,也可以透過 UNC 路徑或 URL 從網路上載入。從磁碟載入的寫法:

If xDoc.Load("C:\My Documents\cds.xml") Then
    ' 文件載入成功,接下來做些有趣的事
Else
    ' 文件載入失敗
End If

用完之後,記得把物件參照釋放掉。MSXML 並未提供明確的關閉方法,最恰當的做法是把參照設為 Nothing:

Set xDoc = Nothing

在預設情況下,解析器被要求載入檔案時是以非同步方式執行的。改動文件的布林屬性 Async 可以改變這個行為。重點是:務必檢查文件的 ReadyState 屬性,確保文件在開始檢查內容之前就已經就緒。MSXML 也暴露了幾個事件,可用來在长期載入時追蹤進度,這在從網路上以非同步方式載入時特別有用。

要從 URL 開啟檔案,必須使用完整的 URL 並加上 https:// 前綴:

xDoc.async = False
If xDoc.Load("https://www.develop.com/hp/brianr/cds.xml") Then
    ' 文件載入成功
Else
    ' 文件載入失敗
End If

把 Async 設為 False,解析器會等到文件完全載入、可操作後才把控制權交回你的程式;設為 True 時,你就必須在存取文件前先檢查 ReadyState,或改用 DOMDocument 的事件在文件就緒時通知程式。

處理載入失敗

基於種種原因,文件載入很可能失敗。最常見的原因是傳給 Load 的檔名無效,另一個常見原因是 XML 文件本身格式不良。

預設情況下,MSXML 會驗證文件中是否指定了 DTD 或結構描述。若想關閉驗證,可在呼叫 Load 之前設定 ValidateOnParse:

Dim xDoc As MSXML.DOMDocument
Set xDoc = New MSXML.DOMDocument
xDoc.validateOnParse = False
If xDoc.Load("C:\My Documents\cds.xml") Then
    ' 文件載入成功
Else
    ' 文件載入失敗
End If

但要先提醒:在正式應用程式中關掉驗證並不是好主意。不正確的文件會基於各種理由讓程式失敗,最起碼也會把無效資料交給使用者。

不論失敗類型為何,都可以透過 ParseError 物件取得詳細錯誤資訊。把參照設為文件自身的 IXMLDOMParseError 介面即可:

Dim xDoc As MSXML.DOMDocument
Set xDoc = New MSXML.DOMDocument

If xDoc.Load("C:\My Documents\cds.xml") Then
    ' 文件載入成功
Else
    ' 文件載入失敗
    Dim strErrText As String
    Dim xPE As MSXML.IXMLDOMParseError

    ' 取得 ParseError 物件
    Set xPE = xDoc.parseError

    With xPE
        strErrText = "Your XML Document failed to load " & _
            "due the following error." & vbCrLf & _
            "Error #: " & .errorCode & ": " & .reason & _
            "Line #: " & .Line & vbCrLf & _
            "Line Position: " & .linepos & vbCrLf & _
            "Position In File: " & .filepos & vbCrLf & _
            "Source Text: " & .srcText & vbCrLf & _
            "Document URL: " & .url
    End With

    MsgBox strErrText, vbExclamation
End If

Set xPE = Nothing

取得這些資訊後,你可以顯示給使用者、寫入錯誤日誌,或自行嘗試修正問題。

從文件中取出資訊

文件載入完成後,下一步就是取出資訊。雖然 DOMDocument 物件很重要,但多數時間你操作的其實是 IXMLDOMNode 介面——它負責讀寫單一節點元素。

開始之前要先知道 MSXML 支援的節點類型(共 13 種),其中幾種最常遇到的是:元素節點(NODE_ELEMENT)、屬性節點(NODE_ATTRIBUTE)、文字節點(NODE_TEXT)、CDATA 區段節點、註解節點、文件節點等。透過 NodeType 屬性可以取得節點類型的列舉值,用 NodeTypeString 則可取得類型的文字名稱。

有了文件參照後,就能在節點階層中移動。ChildNodes 屬性提供了由上而下的入口,可抵達文件中的所有節點;它暴露的 IXMLDOMNodeList 支援 Visual Basic 的 For Each 語法,因此可以逐一列舉每個子節點。此外 ChildNodes 上的 length 屬性可回傳子節點數量。

DOMDocument 不僅暴露 ChildNodes,也暴露了其他所有單一節點。搭配 IXMLDOMNode 的 HasChildNodes 屬性,在節點階層中來回移動、檢查元素、屬性與值就變得相當容易。

這裡有一點必須牢記:元素與元素值之間是主從關係。例如在 CD 文件中,<title> 元素暴露的是歌曲標題這個「欄位」,要取得它的實際文字,必須再往下找 NODE_TEXT 類型的節點。找到感興趣的節點後,可以檢查它的屬性,甚至透過 ParentNode 回溯到它的主節點。

如何在文件中來回移動

因為 XML 文件本身就是分層結構,撰寫遍歷整份文件的遞迴常式相對容易。下面的 LoadDocument 常式負責開啟文件,DisplayNode 則負責實際遍歷:LoadDocument 把文件的 childNodes 當作參數傳入,並帶一個整數指定起始縮排層級,程式用這個縮排參數把輸出格式化成易讀的階層樣子。

DisplayNode 在文件中移動,尋找 NODE_TEXT 類型的節點;找到後用 NodeValue 取出文字,並用當前節點的 ParentNode 取得 NODE_ELEMENT 節點的回溯參照,再透過 NodeName 取得元素名稱,兩者一併輸出。若檢查 HasChildNodes 後確認該節點還有子節點,DisplayNode 便遞迴呼叫自身,直到抵達文件末端。

Public Sub LoadDocument()
    Dim xDoc As MSXML.DOMDocument
    Set xDoc = New MSXML.DOMDocument
    xDoc.validateOnParse = False

    If xDoc.Load("C:\My Documents\sample.xml") Then
        ' 文件載入成功
        DisplayNode xDoc.childNodes, 0
    Else
        ' 文件載入失敗,請參閱前述的錯誤資訊處理
    End If
End Sub

Public Sub DisplayNode(ByRef Nodes As MSXML.IXMLDOMNodeList, _
                       ByVal Indent As Integer)

    Dim xNode As MSXML.IXMLDOMNode
    Indent = Indent + 2

    For Each xNode In Nodes
        If xNode.nodeType = NODE_TEXT Then
            Debug.Print Space$(Indent) & xNode.parentNode.nodeName & _
                          ": " & xNode.nodeValue
        End If

        If xNode.hasChildNodes Then
            DisplayNode xNode.childNodes, Indent
        End If
    Next xNode
End Sub

DisplayNode 用 HasChildNodes 判斷是否要再次呼叫自己;你也可以改用節點的 level 屬性,檢查其值是否大於 0。

XML學習教程| jQuery入門知識| AJAX入門| Dreamweaver教程| Fireworks入門知識| SEO技巧| SEO優化集錦|
Copyright © DIV+CSS佈局教程網 All Rights Reserved