想查一檔股票的即時報價,過去非得開啟專業證券網站、輸入股票代號再翻上幾頁不可。其實只要善用 XMLHTTP,任何人都能在自己的網站上提供一段輕巧的行情查詢服務。本文以 ASP 搭配 VBScript,示範如何串接外部行情資料來源,並讓查詢結果在頁面不閃動、不重新整理的情況下即時帶回。
大型網站通常都有即時更新的行情資料,我們只要由自己的 Web 伺服器送出 XMLHTTP 請求,向財經網站的行情資料庫索取所需欄位,再由 ASP 整理成網頁回傳給瀏覽器即可。
XMLHTTP 的強處在於:它能建立到任意伺服器的 HTTP 連線,送出一段資料、再取回一段資料,而這一切都只要寥寥幾行程式碼就能完成。它最常用於 XML 資料交換,但其他格式同樣可行。商業網站的典型做法是——用戶端送出一段文字字串,伺服器將它載入 XMLDOM 物件加以解析,然後回傳一段 HTML,或回傳另一段 XML 交由用戶端瀏覽器自行解讀。搭配 DHTML 依回傳內容動態更新畫面時,這種傳遞方式特別有效率。
用戶端以 XMLHTTP 提出行情查詢需求 → Web 伺服器上的 ASP 監聽頁收到請求後,改以 XMLHTTP 向行情資料庫發送檢索指令 → 資料庫執行查詢並以 HTML 形式回傳結果 → 我們的伺服器過濾多餘標籤、挑出純粹的股價數據 → 組裝完成後送回用戶端 → 瀏覽器以 VBScript 呈現。
<script language="vbscript">
Sub submit1_onmouseup
Dim objXML, objXSL, objFSO, strFile, strFileName, strXSL, strURL, theString, TheForm
Set TheForm = Document.Wordfind
window.status = "正在檢索資料···"
strURL = "dns2.asp" ' 伺服器監聽頁網址
Set objXML = CreateObject("Microsoft.XMLHTTP") ' 建立 XMLHTTP 元件
strA = "submit=submit&fqdn=" & TheForm.webname.value
objXML.Open "post", strURL, False ' 採用 POST 提交
objXML.setrequestheader "content-length", Len(strA)
objXML.setrequestheader "content-type", "application/x-www-form-urlencoded"
objXML.send strA ' 送出資料
xmlGet = objXML.responsebody ' 取得伺服器回傳內容
xmlGet = bytes2bstr(xmlGet) ' 位元組轉文字,函式見 dns2.asp
TheForm.comments.value = xmlGet
Set objXML = Nothing
End Sub
</script>
<html>
<head>
<title>XMLHTTP 之股票行情篇</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</head>
<body bgColor=#a1bae6>
<table border="0" cellpadding="0" cellspacing="0" width="100%">
<tr><td width="100%" align="center">
<form method="post" name="Wordfind" onsubmit="Javascript:return false">
<font color="#002e5b" face="geneva,arial,sans-serif" size="2">
<b>請選擇股票名稱(美國納斯達克):</b><br>
<select name="webname" style="HEIGHT: 22px; WIDTH: 80px">
<option value="^IXIC">納斯達克</option>
<option value="ASIA">亞信</option>
<option value="CHINA">中華網</option>
<option value="NTES">網易</option>
<option value="SINA">新浪網</option>
<option value="SOHU">搜狐</option>
</select>
<input type="submit" value="查詢" id="Submit1" name="Submit1"></b>
<textarea name="comments" readonly rows="10" cols="76"></textarea>
</font>
</form>
</td></tr></table>
</body>
</html>
<%
dim XMLGet
XMLGet = ""
if Len(Trim(Request.form("fqdn"))) > 1 then
Dim objXML, strURL
' 行情資料庫網址
strURL = "https://cn.finance.yahoo.com/q?s=" + Trim(Request.form("fqdn")) + "&d=2b"
Set objXML = CreateObject("Microsoft.XMLHTTP") ' 建立 XMLHTTP 元件
objXML.Open "get", strURL, False
objXML.Send ' 送出請求
XMLGet = objXML.responsebody ' 取得行情資料
XMLGet = bytes2bstr(XMLGet) ' 轉成文字格式
' 過濾無用的 HTML,取出股票資訊
strFind1 = InStr(1, XMLGet, "最後交易", 1) + 8
strFind2 = InStr(strFind1, XMLGet, "<b>", 1) + 3
strFind3 = InStr(strFind2, XMLGet, "</b></td>", 1)
xmlGet1 = "最後交易:" + Mid(XMLGet, strFind2, strFind3 - strFind2) + vbCrLf
strFind1 = InStr(1, XMLGet, "漲跌", 1) + 4
strFind2 = InStr(strFind1, XMLGet, "<font color=", 1) + 19
strFind3 = InStr(strFind2, XMLGet, "</font>", 1)
xmlGet2 = "漲跌:" + Mid(XMLGet, strFind2, strFind3 - strFind2) + vbCrLf
Set objXML = Nothing
end if
Response.Write Trim(Request.form("fqdn")) + "的股市行情:" + vbCrLf + xmlGet1 + xmlGet2
function bytes2bstr(vin)
strReturn = ""
for i = 1 to LenB(vin)
thischarcode = AscB(MidB(vin, i, 1))
if thischarcode < &h80 then
strReturn = strReturn & Chr(thischarcode)
else
nextcharcode = AscB(MidB(vin, i + 1, 1))
strReturn = strReturn & Chr(CLng(thischarcode) * &h100 + CInt(nextcharcode))
i = i + 1
end if
next
bytes2bstr = strReturn
end function
%>
看完程式不難發現,自家伺服器上的 ASP 其實只扮演「中繼」的角色。實務上也可以拿掉這一層,直接由 VBScript 透過 XMLHTTP 向行情來源送收資料。但 Internet Explorer 預設停用「跨網域存取資料資源」的權限,這種寫法常因權限不足而執行失敗,通用性並不理想,因此保留 ASP 中繼層反而更穩妥。
上述程式在 Windows 2000 平台的 IIS 5.0 與 IE 6.0 上測試通過。把程式碼複製到自己的頁面、稍作版面調整,就能得到一個查詢時不閃爍的股票資訊區塊,乍看之下真有幾分專業證券網站的架勢。